之前写的那篇给出的方法虽然不错，但是当文件过大时（其实很小，也就几M），对应的数组也会很大，然后会出现运行时错误，提示内存耗尽，为此我郁闷了好久。

最近在博客的流量记录中发现百度关键字“一些很恶作剧的vbs程序”（看来现在的年轻人很喜欢玩这口），于是打开久违的百度搜索了一下，发现出现在第三。出现在第二的是百度HI，上面也是一个恶作剧程序，而且还是加密的。我尝试着解密，却发现这个加密似乎比前几天解密的那个病毒更变态，未果。

虽然我没有把那个程序解密出来（如果哪位真正的高手会，麻烦指点一下），但是从中领悟出了用VBS读写二进制文件的另一种方法，即Microsoft.XMLDOM+ADODB.Stream。这个方法的效率比原来那个高得多，而且似乎没有文件大小限制。

Function ReadBinary(FileName) 
Const adTypeBinary = 1 
Dim stream, xmldom, node 
Set xmldom = CreateObject("Microsoft.XMLDOM") 
Set node = xmldom.CreateElement("binary") 
node.DataType = "bin.hex" 
Set stream = CreateObject("ADODB.Stream") 
stream.Type = adTypeBinary 
stream.Open 
stream.LoadFromFile FileName 
node.NodeTypedValue = stream.Read 
stream.Close 
Set stream = Nothing 
ReadBinary = node.Text 
Set node = Nothing 
Set xmldom = Nothing 
End Function 

函数的参数是要读取的文件路径，返回值是包含二进制文件的十六进制值的字符串。

Sub WriteBinary(FileName, Buf) 
Const adTypeBinary = 1 
Const adSaveCreateOverWrite = 2 
Dim stream, xmldom, node 
Set xmldom = CreateObject("Microsoft.XMLDOM") 
Set node = xmldom.CreateElement("binary") 
node.DataType = "bin.hex" 
node.Text = Buf 
Set stream = CreateObject("ADODB.Stream") 
stream.Type = adTypeBinary 
stream.Open 
stream.write node.NodeTypedValue 
stream.saveToFile FileName, adSaveCreateOverWrite 
stream.Close 
Set stream = Nothing 
Set node = Nothing 
Set xmldom = Nothing 
End Sub 

第一个参数是要读入的文件路径，第二个参数是包含二进制文件的十六进制值的字符串。至于如何获得二进制文件的十六进制值，那方法就很多了，最简单的方法当然就是用fso对象将ReadBinary函数的返回值写到文本文件中去，然后Ctrl+C，Ctrl+V。其实用十六进制工具也很简单。

其他的就不多说了，看不懂的多看看MSDN参考文档。写了一个示例程序，里面包含了天空之城音乐的所有数据，双击后在同一文件夹生成天空之城的MP3文件并播放。

原文：http://demon.tw/programming/vbs-binary-file-another.html

在VBS中定义字节数组Byte()介绍
晚上在QQ上看到昵称为乱码的好友回答了搜搜问问里一个问题：在VBS中有办法定义字节数组么？在VBS中有办法定义字节数组么？就是字节子类型数组（Var

用VBS实现的发送带Cookie的HTTP请求的代码
为了方便测试，先写一个回显Cookie的简单的PHP程序：?phpforeach($_COOKIEas$key=$value)echo"$key=$valuern";?然后分别用ServerXMLHTTP和XMLHTTP测试：DimhttpSethttp=CreateObject

校准系统时间的VBS代码
'VBS校准系统时间BYBatManDimobjXML,Url,MessageMessage="恭喜你，本机时间非常准确无需校对！"SetobjXML=CreateObject("MSXML2.XmlHttp")Url="http://open.baidu.com/special/time/"objXML.